| /* SPDX-License-Identifier: GPL-2.0-only */ |
| /* |
| * Hypervisor stub |
| * |
| * Copyright (C) 2012 ARM Ltd. |
| * Author: Marc Zyngier <marc.zyngier@arm.com> |
| */ |
| |
| #include <linux/init.h> |
| #include <linux/linkage.h> |
| #include <linux/irqchip/arm-gic-v3.h> |
| |
| #include <asm/assembler.h> |
| #include <asm/kvm_arm.h> |
| #include <asm/kvm_asm.h> |
| #include <asm/ptrace.h> |
| #include <asm/virt.h> |
| |
| .text |
| .pushsection .hyp.text, "ax" |
| |
| .align 11 |
| |
| ENTRY(__hyp_stub_vectors) |
| ventry el2_sync_invalid // Synchronous EL2t |
| ventry el2_irq_invalid // IRQ EL2t |
| ventry el2_fiq_invalid // FIQ EL2t |
| ventry el2_error_invalid // Error EL2t |
| |
| ventry el2_sync_invalid // Synchronous EL2h |
| ventry el2_irq_invalid // IRQ EL2h |
| ventry el2_fiq_invalid // FIQ EL2h |
| ventry el2_error_invalid // Error EL2h |
| |
| ventry el1_sync // Synchronous 64-bit EL1 |
| ventry el1_irq_invalid // IRQ 64-bit EL1 |
| ventry el1_fiq_invalid // FIQ 64-bit EL1 |
| ventry el1_error_invalid // Error 64-bit EL1 |
| |
| ventry el1_sync_invalid // Synchronous 32-bit EL1 |
| ventry el1_irq_invalid // IRQ 32-bit EL1 |
| ventry el1_fiq_invalid // FIQ 32-bit EL1 |
| ventry el1_error_invalid // Error 32-bit EL1 |
| ENDPROC(__hyp_stub_vectors) |
| |
| .align 11 |
| |
| el1_sync: |
| cmp x0, #HVC_SET_VECTORS |
| b.ne 2f |
| msr vbar_el2, x1 |
| b 9f |
| |
| 2: cmp x0, #HVC_SOFT_RESTART |
| b.ne 3f |
| mov x0, x2 |
| mov x2, x4 |
| mov x4, x1 |
| mov x1, x3 |
| br x4 // no return |
| |
| 3: cmp x0, #HVC_RESET_VECTORS |
| beq 9f // Nothing to reset! |
| |
| /* Someone called kvm_call_hyp() against the hyp-stub... */ |
| ldr x0, =HVC_STUB_ERR |
| eret |
| |
| 9: mov x0, xzr |
| eret |
| ENDPROC(el1_sync) |
| |
| .macro invalid_vector label |
| \label: |
| b \label |
| ENDPROC(\label) |
| .endm |
| |
| invalid_vector el2_sync_invalid |
| invalid_vector el2_irq_invalid |
| invalid_vector el2_fiq_invalid |
| invalid_vector el2_error_invalid |
| invalid_vector el1_sync_invalid |
| invalid_vector el1_irq_invalid |
| invalid_vector el1_fiq_invalid |
| invalid_vector el1_error_invalid |
| |
| /* |
| * __hyp_set_vectors: Call this after boot to set the initial hypervisor |
| * vectors as part of hypervisor installation. On an SMP system, this should |
| * be called on each CPU. |
| * |
| * x0 must be the physical address of the new vector table, and must be |
| * 2KB aligned. |
| * |
| * Before calling this, you must check that the stub hypervisor is installed |
| * everywhere, by waiting for any secondary CPUs to be brought up and then |
| * checking that is_hyp_mode_available() is true. |
| * |
| * If not, there is a pre-existing hypervisor, some CPUs failed to boot, or |
| * something else went wrong... in such cases, trying to install a new |
| * hypervisor is unlikely to work as desired. |
| * |
| * When you call into your shiny new hypervisor, sp_el2 will contain junk, |
| * so you will need to set that to something sensible at the new hypervisor's |
| * initialisation entry point. |
| */ |
| |
| ENTRY(__hyp_set_vectors) |
| mov x1, x0 |
| mov x0, #HVC_SET_VECTORS |
| hvc #0 |
| ret |
| ENDPROC(__hyp_set_vectors) |
| |
| ENTRY(__hyp_reset_vectors) |
| mov x0, #HVC_RESET_VECTORS |
| hvc #0 |
| ret |
| ENDPROC(__hyp_reset_vectors) |
